c = 1.; \[Omega] = 5; d = 0.1; \[Epsilon]0 = 1; q1 = 1; q2 = -1; (*Some constants*)

vd[t_] := {0, 0, \[Omega] d Cos[\[Omega] t]} (*the charge oscillates up and down (this is its velocity) *)

normr = Sqrt[x^2 + y^2 + z^2]; (*just the norm of the position to make the equations easier to type*)
(*Two scalar potentials and two vector potentials, with opposite charges and velocities, to make a dipole*)
\[CurlyPhi]1 =   1/(4 \[Pi] \[Epsilon]0) q1/(normr - vd[t - normr/c].{x, y, z}/c);
\[CurlyPhi]2 =   1/(4 \[Pi] \[Epsilon]0) q2/(normr - ((-1)*vd[t - normr/c].{x, y, z})/c);
A1 = vd[t - normr/c]/c^2 \[CurlyPhi]1;
A2 = ((-1)*vd[t - normr/c])/c^2 \[CurlyPhi]2;

vm = {v, 0, 0}; (*The dipole is moving along x at speed v*)
\[Gamma] =1/Sqrt[1 - v^2/c^2];
(*Let's Lorentz-transform all the potentials and the coordinates*)
\[CurlyPhi]1m = \[Gamma] \[CurlyPhi]1;
\[CurlyPhi]2m = \[Gamma] \[CurlyPhi]2;
A1m = ({\[Gamma] (A1[[1]] - v/c^2 \[CurlyPhi]1m), A1[[2]], A1[[3]]});
A2m = ({\[Gamma] (A2[[1]] - v/c^2 \[CurlyPhi]2m), A2[[2]], A2[[3]]});
\[CurlyPhi]1m = \[CurlyPhi]1m /. {t -> \[Gamma] (t - v/c^2 x), x -> \[Gamma] (x - v t)};
\[CurlyPhi]2m = \[CurlyPhi]2m /. {t -> \[Gamma] (t - v/c^2 x), x -> \[Gamma] (x - v t)};
A1m = A1m /. {t -> \[Gamma] (t - v/c^2 x), x -> \[Gamma] (x - v t)};
A2m = A2m /. {t -> \[Gamma] (t - v/c^2 x), x -> \[Gamma] (x - v t)};

(*Calculate the two fields and their sum (and take a cut along y=0 so we can plot it*)
Efield1m = -Grad[\[CurlyPhi]1m, {x, y, z}] - D[A1m, t];
Efield2m = -Grad[\[CurlyPhi]2m, {x, y, z}] - D[A2m, t];
totEm = Norm[Efield1m + Efield2m] /. {y -> 0};

(*Define a smooth ramp to gradually increase the dipole velocity*)
smoothramp[kink1x_, kink2y_, slope_, \[Epsilon]_, x_] := (slope) \[Epsilon] Log[1 + E^((x - kink1x)/\[Epsilon])] - (slope) \[Epsilon] Log[1 + E^((-kink1x + x)/\[Epsilon])/(-1 + E^(kink2y/(slope \[Epsilon])))];
T = (2 \[Pi])/\[Omega]//N; (*Calculate the dipole oscillation period, so we can make sure we sample often enough in time*)

(*Plot everything*)
v =.
frames = Table[
   v = smoothramp[5 T, 0.75, 0.02, 1, \[Tau]];
   Grid[{{
      DensityPlot[
       totEm /. {t -> \[Tau]}, {x, -10 + v*\[Tau], 10 + v*\[Tau]}, {z, -10, 10}, PlotPoints -> 100, PlotRange -> {{-10 + v*\[Tau], 10 + v*\[Tau]}, {-10, 10}, {-0.01, 0.5}}, ColorFunction -> "AvocadoColors", 
       Frame -> False, PlotLegends -> BarLegend["AvocadoColors", LegendLabel -> "|\!\(\*OverscriptBox[\(E\), \(\[Rule]\)]\)|", LabelStyle -> {Black, Bold}, LegendMarkerSize -> 200, Ticks -> None], ImageSize -> 300 ]
      ,
      Plot[
       totEm /. {t -> \[Tau], z -> 0}, {x, -10 + v*\[Tau], 10 + v*\[Tau]}, PlotRange -> {{-10 + v*\[Tau], 10 + v*\[Tau]}, {-0.01, 0.5}}, PlotStyle -> {Thick, Black}, Axes -> False, Frame -> True, ImageSize -> 300, FrameTicks -> None, FrameLabel -> {"x", "|\!\(\*OverscriptBox[\(E\), \(\[Rule]\)]\)|"}, LabelStyle -> {Black, Bold}, PlotLabel -> Text[Style[StringForm["v=``c", NumberForm[v, {3, 2}]], Black, Bold]]]
      }}]
   , {\[Tau], 0., 31 T, 0.1 T}];
ListAnimate[frames, 10]

I, the copyright holder of this work, hereby publish it under the following license:

This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication.

The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission. http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse