Wikidata

Wikidata:WikiProject Honoris Causa France

Cette page a vocation à coordonner les actions menées en terme de signalement des attributions de honorary doctorate (Q11415564) par les universités françaises. Collecte des données réalisée à l'aide de plusieurs sources : données fournies par les universités, dépouillement manuel et automatisé du Journal officiel, presse (notamment Le Monde pour la période 1944-1990), sites des universités et de leurs archives sur Internet Archive et alerte Google.

Principaux problèmes rencontrés : identifitcation des personnes (certaines sources n'indiquent pas le prénom ou juste l'initial et même avec le prénom, dans certains cas il faudrait avoir le métier / la discipline pour correctement identifier la personne), le JO ne permet pas de savoir si le doctorat a bien été remis/accepté, certaines sources se mélangent les pinceaux suite aux fusions et scissions d'universités.

Projet initié début juin 2024. Six mois plus tard, la base comporte 4153 doctorats honoris causa provenant de 130 institutions. 8 % a été décerné à des femmes. Le récipiendaire du plus grand nombre de doctorats est Abdou Diouf (Q219728) avec 11 doctorats. La couverture est encore inégale. Les 50 premières années de distribution des doctorats honoris causa, soit de 1918 à 1967, sont très bien couverts.

Cas particuliers
  • Des français figurent parmi les récipiendaires. S'ils ne possèdent que la nationalité française, pourquoi ont-ils un DHC ? ex. Jean de Lattre de Tassigny (Q81114)
  • Quelques DHC décernés par Strasbourg durant l'administration allemande avant que cela soit autorisé en France
  • Publication au JORF après l'indépendance du Sénégal. Est-ce un retard de publication ou bien lié au fait que la France assurait la gestion de l'université post-indépendance ? (source) ex. William Everett Welmers (Q106441256)
  • Plusieurs mentions de DHC au JO mais ne figurant pas dans la liste officielle de l'université : oubli, arrêté sans cérémonie... Quel est le statut légal si la cérémonie n'a jamais lieu ? ex. Bhumibol Adulyadej (Q855252)
  • Déclarations dépréciées venant généralement de la Wikipédia germanophone, cf requête ci-dessous, ex. Nicolaus Heutger (Q1671603) Ronald Oxburgh, Baron Oxburgh (Q2165718)
  • Autre motif de dépréciation : retrait de la DHC à Blaise Compaoré (Q57324)

À faire

edit
 
Aide-mémoire
  • Terminer l'intégration des données extraites du JORF pour les années 1990
  • Poursuivre le dépouillement du JO sur Légifrance
  • Améliorer la requête SPARQL sur l'âge en retirant les dates imprécises (décennies et siècles)
  • Réduire la liste des DHC non identifiés
  • Essayer de bien ranger les DHC anachroniques
  • Ajouter des requêtes SPARQL pertinentes
  • Traduire les libellés des DHC afin que cela s'affiche correctement dans les versions linguistiques de Wikipédia qui affichent les données de Wikidata
  • Mettre en place un Google Custom Search Engine pour chercher dans l'ensemble des sites web des universités
Mal rangé
Autres problèmes de qualité des données
A identifier
  • DHC Aix-Marseille :
    • DADI (Italie), MAC ILWAIN (GB), R. BERGUER, W.K. ENGEL, V. ASKANAS, J. PORTER, J. Edward MC DADE (USA), J.G. MC LEOD (Australie) source
    • Mac Intosh source
    • Mac Kean source
    • Kenneth Moye Greenland source
  • DHC Besançon :
  • DHC Nantes : Singer et Dufly source
  • DHC Poitiers : Burgers, Poss, Harrod, Garrod, Sapori source
  • DHC Rouen 
Grande-Bretagne: Lord Reay, G. H. Nutalli, Burnham, Henry Read
Belgique : P. Frederick, Dupriez
Yougoslavie : Novacovic
  • DHC Toulouse II : John Anderson (2003) source
Points à clarifier

Complétude des données

edit
  • Bourgogne, 1984-2018  Y
  • Picardie 13 sur 22
    • Lenglé 19e
    • Murray 21e
    • Renzo Piano 22e

Sur Wikipédia

edit
  • Mentionner les DHC dans les biographies
  • Catégoriser les biographies (cf fr:Catégorie:Docteur honoris causa d'une université en France)
  • Traduire les libellés Wikidata afin que ça s'affiche dans la langue locale sur Wikipédia lorsque l'infobox récupère l'info de Wikidata (français, grec, hongrois, catalan, roumain, suédois)


L'équipe

edit

Propriétés

edit

La plupart des doctorats disposent d'alias permettant de taper DHC Paris, DHC Aix, DHC Grenoble pour trouver facilement la distinction souhaitée.

award received (P166)
  Honorary doctorate from the University of Paris 1 Pantheon-Sorbonne (Q126416227) edit
point in time 3 mars 1990
announcement date 3 décembre 1990
speaker Camille Noûs (Q96603575)
0 references
add reference
add value

Requêtes SPARQL

edit

Organisations

edit
Nombre d'institutions françaises délivrant des DHC
SELECT (COUNT(*) AS ?count)
WHERE {
  ?DHC wdt:P279 wd:Q11415564.
  ?DHC wdt:P17 wd:Q142.}
Try it!
Liste des entités wikidata existantes pour des honoris Causa délivrés par des institutions françaises
SELECT ?DHC ?DHCLabel
WHERE
{
  ?DHC wdt:P279 wd:Q11415564.
  ?DHC wdt:P17 wd:Q142.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} order by ?DHCLabel
Try it!

Évolution de la couverture :

  • 09/06/2024 : 106 doctorats ;
  • 20/06/2024 : 120 doctorats ;
  • 29/11/2024 : 130 doctorats ;

Doctorats

edit
Nombre de DHC décernés
SELECT (COUNT(*) AS ?count)
WHERE {
  ?item wdt:P166 ?DHC.
  ?DHC wdt:P279 wd:Q11415564.
  ?DHC wdt:P17 wd:Q142.
}
Try it!
Nombre de DHC décernés par année
SELECT ?annéeDHC  (COUNT(?annéeDHC) AS ?count) 
WHERE {
  ?item wdt:P166 ?DHC.
  ?DHC wdt:P279 wd:Q11415564.
  ?DHC wdt:P17 wd:Q142.
  
  ?item p:P166 ?node.
  ?node ps:P166 ?DHC.
  ?node pq:P585 ?dateDHC.
  BIND  (YEAR(?dateDHC) AS ?annéeDHC)
}
GROUP BY ?annéeDHC
ORDER BY ?annéeDHC
Try it!
Liste des doctorats délivrés
SELECT ?item ?itemLabel ?DHCLabel
WHERE
{
  ?item wdt:P166 ?DHC.
  ?DHC wdt:P279 wd:Q11415564.
  ?DHC wdt:P17 wd:Q142.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Try it!

Évolution de la couverture :

  • 08/06/2024 : 577 doctorats ;
  • 09/06/2024 : 1388 (chargement des doctorats issus du JORF en particulier) ;
  • 20/06/2024 : 1794
  • 22/06/2024 : 1786 (le chiffre a diminué suite à la suppression des professeurs honoris Causa délivrés par HEC qui ne sont pas des doctorats honoris causa à proprement parler)
  • 25/06/2024 : 2078
  • 29/07/2024 : 3104
  • 29/11/2024 : 3548

Personnes distinguées

edit
Nombre de doctorats par personne
SELECT ?item ?itemLabel (COUNT (?DHC) AS ?doctorats)
WHERE
{
  ?item wdt:P166 ?DHC.
  ?DHC wdt:P279 wd:Q11415564.
  ?DHC wdt:P17 wd:Q142.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

GROUP BY ?item ?itemLabel ?doctorats
ORDER BY DESC(?doctorats)
Try it!
  • 29/11/2024 : 11 doctorats (Abdou Diouf), puis 10 doctorats (François Louis Ganshof)
Doctorats délivrés à des personnes qui ont été premier ministre avant ou après
SELECT ?item ?itemLabel ?itemDescription ?DHCLabel
WHERE
{
  ?item wdt:P166 ?DHC.
  ?DHC wdt:P279 wd:Q11415564.
  ?DHC wdt:P17 wd:Q142.
  ?item wdt:P39/wdt:P279* wd:Q14212.
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER BY ?itemLabel
Try it!

Biais de genre

edit
Nombre de doctorats délivrés à des femmes et personnes non-binaires
SELECT (COUNT(*) AS ?count)
WHERE
{
  ?item wdt:P166 ?DHC.
  ?DHC wdt:P279 wd:Q11415564.
  ?DHC wdt:P17 wd:Q142.
  
  ?item p:P166 ?node.
  ?node ps:P166 ?DHC.
  ?node pq:P585 ?dateDHC.
  
  MINUS{?item wdt:P21 wd:Q6581097.}

}

ORDER BY ?annéeDHC
Try it!
Doctorats délivrés à des femmes et personnes non-binaires
SELECT ?item ?itemLabel ?DHCLabel (YEAR(?dateDHC) AS ?annéeDHC)
WHERE
{
  ?item wdt:P166 ?DHC.
  ?DHC wdt:P279 wd:Q11415564.
  ?DHC wdt:P17 wd:Q142.
  
  ?item p:P166 ?node.
  ?node ps:P166 ?DHC.
  ?node pq:P585 ?dateDHC.
  
  MINUS{?item wdt:P21 wd:Q6581097.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}

ORDER BY ?annéeDHC
Try it!
  • 30/11/2024 : 270
Nombre de doctorats décernés par établissement et genre
SELECT ?DHC ?DHCLabel (count(*) as ?count) ?genreLabel
WHERE {
   
   {
  ?item wdt:P166 ?DHC.
  ?item wdt:P21 ?genre.
  ?DHC wdt:P279 wd:Q11415564.
  ?DHC wdt:P17 wd:Q142.
   
   }
  
   SERVICE wikibase:label {
    bd:serviceParam wikibase:language "fr, en" .
   }

 } 

GROUP BY ?DHC ?DHCLabel ?genreLabel
ORDER BY ?DHCLabel
Try it!

Cartes

edit
Carte des récipiendaires par lieu de naissance
#defaultView:Map
SELECT ?person ?personLabel ?coord ?DHCLabel ?Naissance ?cityLabel ?layer
WHERE {
  ?person wdt:P166 ?DHC.
  ?DHC wdt:P279 wd:Q11415564.
  ?DHC wdt:P17 wd:Q142.
  
  ?person wdt:P19 ?city.
  ?city wdt:P625 ?coord.			
  
  ?person wdt:P569 ?Naissance.

  BIND(
  IF(?Naissance < "1850-01-01T00:00:00Z"^^xsd:dateTime, "<1850",
  IF(?Naissance < "1900-01-01T00:00:00Z"^^xsd:dateTime, "<1900",
  IF(?Naissance < "1950-01-01T00:00:00Z"^^xsd:dateTime, "<1950",
  IF(?Naissance < "2000-01-01T00:00:00Z"^^xsd:dateTime, "<2000",
  "21e siècle"))))
  AS ?layer).
  
  MINUS{VALUES ?DHC {wd:Q111164672 wd:Q99976322}.} 
 
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr"}
 }
Try it!

Requêtes pour contribuer

edit
Personnes sans biographie sur la Wikipédia francophone
SELECT DISTINCT ?item ?itemLabel 
WHERE
{
  ?item wdt:P166 ?DHC.
  ?DHC wdt:P279 wd:Q11415564.
  ?DHC wdt:P17 wd:Q142.

MINUS {
  ?frArticle schema:about ?item; 
             schema:isPartOf <https://fr.wikipedia.org/>. }

SERVICE wikibase:label { bd:serviceParam wikibase:language "fr" }
}
ORDER BY ASC(?item)
Try it!

Pour une liste limitée aux personnes sur la Wikipédia anglophone mais absent de la Wikipédia francophone : https://w.wiki/BAj3

  • 12/09/2024 : 1749 personnes
Sources utilisées
SELECT ?item ?itemLabel ?DHCLabel (SAMPLE(?ref) as ?ref) (SAMPLE(?url) as ?url) (SAMPLE(?affirme) as ?affirme) (SAMPLE(?archive) as ?archive)
WHERE
{
  ?item p:P166 ?statement.
  ?statement ps:P166 ?DHC .
  ?DHC wdt:P279 wd:Q11415564.
  ?DHC wdt:P17 wd:Q142.
  OPTIONAL {
    ?statement prov:wasDerivedFrom ?ref .
    ?ref pr:P854 ?url
  }
  OPTIONAL {
    ?statement prov:wasDerivedFrom ?ref .
    ?ref pr:P248 ?affirme
  }
  OPTIONAL {
    ?statement prov:wasDerivedFrom ?ref .
    ?ref pr:P1065 ?archive
  }  
  
  MINUS{VALUES ?DHC {wd:Q111164672 wd:Q99976322}.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
group by ?item ?itemLabel ?DHCLabel

ORDER BY ?ref
Try it!
Importé de
SELECT ?item ?itemLabel ?DHCLabel (SAMPLE(?ref) as ?ref) (SAMPLE(?url) as ?url)
WHERE
{
  ?item p:P166 ?statement.
  ?statement ps:P166 ?DHC .
  ?DHC wdt:P279 wd:Q11415564.
  ?DHC wdt:P17 wd:Q142.
  ?statement prov:wasDerivedFrom ?ref .
  ?ref pr:P143 ?url
  MINUS{VALUES ?DHC {wd:Q111164672 wd:Q99976322}.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
group by ?item ?itemLabel ?DHCLabel
Try it!
Liste des déclarations de DHC avec un rang obsolète (= généralement faute de source)
SELECT ?item ?itemLabel ?DHCLabel
WHERE
{
  ?item p:P166 ?statement.
  ?statement ps:P166 ?DHC .
  ?statement wikibase:rank wikibase:DeprecatedRank .
  
  ?DHC wdt:P279 wd:Q11415564.
  ?DHC wdt:P17 wd:Q142.
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}
Try it!


Complétude des entrées sur les personnes
Voir User:Jean-Frédéric/DHC pour un tableau des bord, université par université des lacunes présentes sur les entrées concernant les personnes ayant reçu un doctorat.

Sources d'alimentation

edit

Sources utilisées : Journal officiel, presse (dont la presse ancienne sur Gallica et les archives du Monde), sites institutionnels (ainsi que les versions archivées par Internet Archive et les comptes Instagram), thèses, articles scientifiques, livret de l'étudiant

Avant 1990

edit

Pas de source identifiée avant cette date qui permette d'avoir une synthèse des doctorats délivrés. Pistes possibles :

  • listes consolidées fournies par les établissements quand elles existent ;
  • JORF :
    • Internet Archive (1941-1961)  Y
    • Gallica (1881-1953)  Y
    • Légifrance : à partir de 1946, noter les numéros de pages dans la table analytique annuelle puis chercher dans les JORF. cf https://notes.wikimedia.fr/p/DHC. Avancement : 1946, 1962-1970, 1989  Y

1990 - 2002 : JORF

edit

Jusqu'en 2002, les propositions de doctorats honoris causa étaient validées par un arrêté publié au Journal officiel de la République française (Q1815103). Une opération a été menée le 9 juin 2024 par symac qui a consisté à :

  • extraire tous les arrêtés contenant la chaine "honoris causa" ;
  • analyser le contenu de l'arrêté pour trouver : la personne concernée / l'établissement / la date de l'arrêté ;
  • lier la personne à une entité wikidata existante ;
  • ajouter la award received (P166) ;

Cette opération a permis la création de 859 entrées sur wikidata. Il reste 93 arrêtés qui n'ont pas été traités en semi-automatique car ils concernaient plusieurs personnes ou que la personne concernée n'a pas pu être identifiée avec certitude :

  • 74 arrêtés dont le récipiendaire n'a pas pu être lié à une entité wikidata, colonne I (identifiant wikidata) et J (commentaire) à compléter en fonction des trouvailles (61 à faire) ;
  • 19 arrêtés correctifs, ou concernant plusieurs personnes, non traités de manière automatisée, à traiter manuellement, mettre à jour la colonne A "Traitement OK" lorsque le traitement est effectué (1 à faire)

2002 - 2024 : Application SIREDO du Ministry of Higher Education and Research (Q2726949)

edit

D'après la circulaire MENR0201451C du ministère ministre de la jeunesse, de l'éducation nationale et de la recherche, les doctorats honoris causa doivent être remontés chaque année par les établissements dans l'enquête SIREDO.

Une demande d'accès aux documents administratifs a été faite pour obtenir cette liste consolidée le 9 juin 2024 : https://madada.fr/demande/liste_des_doctorats_honoris_caus

Listes publiées par les établissements

edit
Tableau d'avancement
Établissement Élément Wikidata Travail à réaliser État d'avancement
Université de Pau Q113547178 Liste déjà complète et validée avec l'établissement
Université Lyon 1 Q126373749 Attendre le retour au mail envoyé à l'administration Données intégrées
Université de Bourgogne/Dijon Q117250955 Mail à rédiger à l'administration Données intégrées issues de l'ouvrage Q125927215 au cours d'un exercice donné en TP)
Université de Strasbourg Exemple Extraction incomplète réalisée Me contacter
Université de Strasbourg Docteurs Honoris causa de l’université de Strasbourg de 1920 à 1939 Données intégrées
Université de Savoie Q126416272 Attendre le retour au mail envoyé à l'administration Données intégrées
Université de Franche-Comté Q126416273 Attendre le retour au mail envoyé à l'administration Données intégrées
Université Jean Monnet Q126416283 Attendre le retour au mail envoyé à l'administration Données intégrées
Université Lyon III Q126416260 Attendre le retour au mail envoyé à l'administration Données intégrées
Université Lyon 2 Q126416268 Attendre le retour au mail envoyé à l'administration Données intégrées
Museum de Paris Q126416291 Attendre le retour au mail envoyé à l'administration Données intégrées
ENS de Lyon Q111143897 Mail à rédiger à l'administration Données intégrées
Université de Bordeaux Q93578093 Liste complète depuis 2014 et validée avec l'établissement
Bordeaux 1 Archive
Bordeaux 2 Archive
Bordeaux 4 Archive
Grenoble 1 Q126416278 Contact établi avec Grenoble, en attente de l'intégration des autres structures Données intégrées
Grenoble 2 Q126416270 Contact établi avec Grenoble, en attente de l'intégration des autres structures Pas trouvé la page sur le site internet. Données parcellaires.
Grenoble 3 Q126416286 Contact établi avec Grenoble, en attente de l'intégration des autres structures Données intégrées.
Grenoble Alpes Q126728033 Contact établi avec Grenoble, en attente de l'intégration des autres structures Données intégrées
COMUE de Lyon Q126737039 Attendre le retour au mail envoyé à l'administration Données intégrées
INSA de Lyon Q126416288 Attendre le retour au mail envoyé à l'administration Données intégrées
Université Blaise Pascal Q110750537 Mail à rédiger à l'administration Données intégrées
Institut polytechnique de Grenoble Q126416269 Mail à rédiger à l'administration Données intégrées
École centrale de Lyon Q126908141 Attendre le retour au mail envoyé à l'administration Données parcellaires
Université de Tours Q494335 WD en a 3 de plus que l'université[1] Données intégrées
Paris I liste depuis 2000 Données intégrées
Paris II intégrer la liste de leur site  Y intégration complétée via OpenRefine (groupe d'éditions)
Paris III intégrer la liste de leur site  Y intégration complétée via QuickStatement (groupe d'éditions)
Paris VII tag dédié dans les actualités Données intégrées
Paris VIII intégrer la liste de leur site  Y intégration complétée via QuickStatement (groupe d'éditions)
Paris X liste incomplète, autre liste incomplète Données intégrées
université de Bretagne-Sud Envoyer un mail pour vérifier la liste Données intégrées
Université de Bretagne-Occidentale Envoyer un mail pour vérifier la liste Données intégrées
Polynésie française Envoyer un mail pour vérifier la liste Données intégrées
Lorraine liste depuis 2012 Données intégrées
Nantes page présentation des lauréats sur leur site Données intégrées
Rennes-I Le Doctorat Honoris Causa à l'Université de Rennes Données intégrées en totalité (71 et l'univ annonce 78 décorées)
Toulouse I Fichier PDF Données intégrées (un en plus au JORF en 2001 : pas de cérémonie ?)
Toulouse II post Instagram Données intégrées
Université d'Artois Envoyer un mail pour vérifier la liste Données intégrées
Université de Cergy-Pontoise Envoyer un mail pour vérifier la liste Données intégrées
université polytechnique Hauts-de-France Envoyer un mail pour vérifier la liste Données intégrées
Université de La Rochelle Envoyer un mail pour vérifier la liste Données intégrées
Université de Perpignan https://books.openedition.org/pupvd/3681 Données intégrées
Université Dauphine Envoyer un mail pour vérifier la liste Données intégrées
compléter ici compléter ici compléter ici

Réutilisation des données

edit
  • Les données de wikidata sont réutilisées pour alimenter le site https://honoris-causa.geobib.fr/ (en cours de développement en juin 2024)
  • Publication du jeu de données de Pau sur Data ESR.
  • il pourrait être intéressant de publier un jeu de données sur une plateforme open data dans un format CSV facilement exploitable ? (mais quid de la mise à jour, peut-être plus utile de documenter la manière de faire)

Notes

edit
  1. ↑ Personne à contacter

Bibliographie

edit
Retrieved from "https://www.wikidata.org/w/index.php?title=Wikidata:WikiProject_Honoris_Causa_France&oldid=2289774134"
  NODES
admin 16
INTERN 4
Note 4
Project 3
todo 1